The sasServerPage stored process simply calls a macro called sasServerPage. This allows the macro to be called from other stored processes or programs as needed:

*ProcessBody;

%sasServerPage(fileref = &srvrpgs       /* SAS Server Pages aggregate fileref */

              ,page = &page            /* name of the SAS Server Page to use */

              ,quoting = &quoting      /* quoting option for PROC STREAM */

              ,asis = &asis            /* asis option for PROC STREAM */

              ,noAbSSCmt = &noAbSSCmt  /* noAbsSCmt option for PROC STREAM */

              )

The specified parameters to the macro are also stored process parameters. Default values are assigned in the definition of the stored process for each parameter. These values correspond to PROC STREAM's parameters:

• The fileref parameter specifies an assigned fileref for an aggregate location (a directory or set of concatenated directories) where the input SAS Server Pages are stored.

• The page parameter specifies the name of the SAS Server Page to be processed.

• The quoting parameter specifies the handling of single and double quotation marks (the value to be used for the PROC STREAM quoting parameter).

• The asis parameter is either blank or has the value &asis (corresponding to the like-named PROC STREAM parameter).

• The noAbsSSCmt parameter is either blank or has the value &noAbsSSCmt (corresponding to the like-named PROC STREAM parameter).

The sasServerPage macro source follows:

%macro sasServerPage

       (fileref = srvrpgs               /* fileref for server page locations   */

       ,page =                         /* list of server pages               */

       ,defaultExtension = html        /* default extension if not provided  */

       ,outfile = _webout               /* destination to write output to     */

       ,mod =                          /* mod if appending to &outfile        */

       ,quoting = both                 /* single/double quote handling       */

       ,asis =                         /* attempt to preserve columns/ASIS   */

       ,noAbSSCmt =                    /* include slash-star comments        */

       );

 %local quot amp apos lt gt nbsp copy reg;

 %let quot = "

 %let amp = &

 %let apol = '

 %let lt = <

 %let gt = >

 %let nbsp =  

 %let copy = ©

 %let reg = ®

 %if %scan(&page,2,.) = %then %let page = &page..&defaultExtension;

 proc stream outfile = &outfile &mod &asis &noAbSSCmt

             %if %length(&quoting) > 0 %then quoting=&quoting;

 ;

   BEGIN

   %include &fileref(&page);

 ;;;;

 run;

%mend sasServerPage;

Note that the macro has three additional parameters not defined as parameters for the stored process because they rarely, if ever, need to be modified from their default values when the macro is run from the stored process. They are likely to be used when the sasServerPage macro is called directly from another SAS program:

• the output location, outfile, which for a stored process is almost always _webout.

• the mod, which in the stored process (and SAS/IntrNet Application Dispatcher) environment is always enabled.

• the defaultExtension, which again is almost always html. (Note that in a stored process environment the default extension is not used if the extension is included in the value of the page parameter.)

A simple version of a runMacro stored process source follows. The name of the macro to run is passed as an input parameter.

*ProcessBody;

%stpbegin;

%put NOTE: Execute macro &macroToRun..;

%&macroToRun

%stpend;

In section 2.2.1, an example was shown where the user was prompted to select the products to be included in a report. That sample invoked the selectedProductsReport macro, which subset the data and ran a PROC REPORT step on the product values selected by the user.

Recall that the example shown in section 2.2.1 included a number of desirable features:

• the ability to show the output in the same window as the user interface where the user specified which products to include in the report

• the ability to show or hide the selection form so as to maximize the amount of screen real estate for the output, while still allowing for easy access to the selection user interface for making changes

• the ability to show a processing image to alert the user that the report is running—something that is important for reports that don't return results immediately

Instead of duplicating the HTML (and JavaScript) that provides this functionality in each and every SAS Server Page that is used to prompt the user for parameters, the following examples leverage the %INCLUDE facility of PROC STREAM. That facility allows for the development of a standard structure for your reports and user interfaces without requiring duplication of code. Storing common code in an external file and using the %INCLUDE statement to include the output created by PROC STREAM should be considered a best practice. Such SAS Server Pages contain at least three sections:

• The first section simply uses %INCLUDE to define a standard page header.

• The next part is the specific HTML, including macro variable references and macros, to generate the user interface for the subject report accessed as a stored process (in this case the selectedProductsReport macro run by the runMacro stored process).

• The last section simply uses %INCLUDE to define a standard page trailer.

This technique has broad applicability as the header or trailer section can also be used to display application or corporate logos, including confidentiality or copyright text, and so on.

Figure 5.1: Video of Two Alternative User Interfaces

The following two SAS Server Pages generate the user interfaces shown in the video in Figure 5.1. The first one uses a select tag and the second one uses check boxes to prompt users to specify the products they want to include.

%global pageTitle macroToRun _debug;

%let pageTitle=Products Select Tag;

%let macroTorun=selectedProductsReport;

&streamDelim;%include &srvrpgs(stpHeader.html);

%let rc = %sysfunc(dosubl(%nrbquote(

%getDistinct(data=sashelp.shoes

            ,vars=product

            ,out=productList)

)));

%generateOptionTag(data=productList

                  ,var=product

                  ,otherOptions=multiple size=&sqlobs)

 <p><input type="submit" value="Run Report">

&streamDelim;%include &srvrpgs(stpTrailer.html);

The sample header and trailer SAS Server Pages, as well as the getDistinct and generateOptionTag macros, are described in the following subsections.

Check boxes can be simpler for the user (they don't need to know about using the CNTL key) if multiple selections are allowed. The following SAS Server Page (output shown in Figure 5.2) demonstrates this technique to create a set of check box fields. It uses the same standard header and trailer server pages as described previously, thus allowing the page to focus on just the functionality needed for the specific user interface components for the desired report.

Figure 5.2: A Prompt Page Using Check Boxes

%global pageTitle macroToRun _debug;

%let pageTitle=Products Checkboxes;

%let macroTorun=selectedProductsReport;

&streamDelim;%include &srvrpgs(stpHeader.html);

%let rc = %sysfunc(dosubl(%nrbquote(

 proc sql noprint;

 select distinct cats(‘&streamDelim newline;<input type="checkbox" name="product" value="‘,strip(product),’">’

                      ,strip(product)

                     )

 into:checkBoxes separated by ‘<br>’

 from sashelp.shoes;

 quit;

)));

&checkboxes

<p><input type="submit" value="Run Report">

&streamDelim;%include &srvrpgs(stpTrailer.html);

The stpHeader SAS Server page is an example of packaging reusable functionality to create custom user interfaces for stored processes. It illustrates how using PROC STREAM can enable you to create sophisticated custom user interfaces, and it packages the following capabilities:

• displaying the user interface side by side in a single window with the output from the submitted stored process

• toggling the user interface display on and off, thus freeing up screen real estate for the output of the stored process

• displaying a message and an image that highlights to the user that the stored process has been submitted and is running

• including standard text at the bottom of the page

The following source can be easily changed and customized in order to suit the needs of your stored processes, thus enabling you to create any number of alternative user interfaces. A basic understanding of HTML and JavaScript by the reader is assumed.

%global pageTitle macroToRun _debug;

%let _debug = %sysfunc(coalesceC(&_debug,0));

<html> <head>

<script> 

function toggleForm() {

 if (document.getElementById(‘showForm’).style.display == ‘none’)

 { document.getElementById(‘showForm’).style.display = ‘block’;

   document.getElementById(‘hideForm’).style.display = ‘none’;

   document.getElementById(‘form’).style.display = ‘none’;

 }

 else

 { document.getElementById(‘form’).style.display = ‘block’;

   document.getElementById(‘hideForm’).style.display = ‘block’;

   document.getElementById(‘showForm’).style.display = ‘none’;

 }

}

function processing() {

 window.frames(‘results’).document.body.innerHTML =

   ‘<center>’

 + ‘<b><i>Please Wait</i></b>’

 + ‘<p><img src="/SASStoredProcess/images/progress.gif">’

 ;

 toggleForm();

}

</script>

<title&pagetitle</title> </head> <body>

<a id="showForm"

   href="JavaScript:toggleForm();"

   title="Show Selections"

   style="text-decoration:none; display:none;">

<img src="/SASStoredProcess/images/arrow-right-default.gif"

     border="0">

</a>

<a id="hideForm"

   href="JavaScript:toggleForm();"

   title="Hide Selections"

   style="text-decoration:none; display:block;">

<img src="/SASStoredProcess/images/arrow-left-default.gif"

     border="0">

</a>

<table style="width:100%; height:100%;">

<tr>

<td id="form"

    style="float:left; display:block; vertical-align:top">

<form action="&_url"

      target="results"

      onSubmit="processing();">

<input type="hidden"

       name="_program"

       value="&_metafolder.runMacro">

<input type="hidden"

       name="macroToRun"

       value="&macroTorun">

<input type="hidden"

       name="_debug"

       value="&_debug">

The stpTrailer SAS Server Page is included by the calling SAS Server Page to close the form and to define the display area for the stored process output. Like the stpHeader SAS Server page, it can be easily changed and customized in order to suit the needs of your stored processes.

</form>

</td>

<td style="overflow-x:hidden; display:block; vertical-align:top">>

<iframe name="results"

        width="100%"

        height="100%"

        frameborder="0">

</iframe>

</td> </tr>

<tr>

<td colspan="2" style="height:15; background-color:#E4E4E4; color:#999999; font-family:Geneva, Arial, Helvetica, sans-serif; font-size:10px; font-style:italic;">

<div style="float:left;">

<a href="http://www.sascommunity.org/wiki/SAS%C2%AE_Server_Pages:_Generating_Dynamic_Content"

 style="text-decoration:none" target="_blank">

SAS® Server Pages: Generating Dynamic Content

</a>

</div>

<div style="float:right;">

<a href="http://www.hcsbi.com"

   style="text-decoration:none" target="_blank">

Henderson Consulting Services

</a>

</div>

</td>

</tr>

</table> </html>

The getDistinct macro is an example of a simple utility macro that can be stored in a macro autocall directory and used whenever a list of distinct values is needed. It has the following parameters:

• The data parameter specifies the name of the data set from which the distinct values are to be obtained.

• The vars parameter specifies the variable(s) for which the distinct values (or distinct combinations if multiple variables are listed) are desired. A distinct list of combinations of values could be used, for example, when creating cascading select tags.

• The out parameter specifies the name of the output data set containing the default values. The DATAn convention is the default.

%macro getDistinct

     (data =          /* name of data set */

     ,vars =          /* list of variables for the select distinct */

     ,out = _data_    /* output data set name */

     );

 /* convert var list to csv for use in SQL */

 %let vars = %sysfunc(compbl(&vars));

 %let vars = %sysfunc(translate(&vars,%str(,),%str( )));

 proc sql noprint;

  create table &out as 

  select distinct &vars

  from &data;

 quit;

%mend getDistinct;

The generateOptionTag macro reads the rows in the input data set using the data access functions (OPEN, CLOSE, FETCH, GETVARC, GETVARN) that are executed using the %SYSFUNC macro.

The macro has the following parameters:

• The data parameter specifies the name of the data set to use to populate the select tag.

• The var parameter specifies the name of the variable that provides the value (that is, that value submitted to the server when the form is submitted) for the option tag.

• The label parameter specifies the name of the variable that provides the label (the visible text) for the option tag. If not provided, it defaults to the value of the var VAR parameter.

• The name parameter specifies the name of the select tag form field. If not provided, it defaults to the value of the var parameter.

• The where parameter specifies an optional WHERE clause used to subset the data set specified in the data parameter.